/****************************************************************************/
/*  Nevis DSP6202 link file                                                 */
/*  S. Simion 23-Aug-2000                                                   */
/****************************************************************************/
-c
-heap  0x2000
-stack 0x4000
-l ../LIB/Nevis6000.lib
-m a.map

/*
	Memory Map 1
	CE1H  is the second half of the dual-port RAM viewed by the DSP
	PMEM  is the 128K Bytes program memory
	BMEM0 is the 128K Bytes data memory in block 0
	BMEM1 is the 128K Bytes data memory in block 1
*/

MEMORY
{
	VECS:		o = 00000000h	l = 00000200h
	PMEM:		o = 00000200h   l = 0000fc00h
	ROM2(IR):	o = 00010000h	l = 00010000h
	CE1H(R):	o = 01410000h	l = 00010000h
	BMEM0(RW):	o = 80000000h   l = 00010000h
	BMEM1(RW):	o = 80010000h	l = 00010000h
}

/*
   The .cc_init section contains 16K Bytes of space for non-cinit 
   run-time initialization, namely calibration constants. 
   It has _cc_init symbol attached, normally CE1H.
*/

SECTIONS
{
	vectors:	>VECS
	.text:		>PMEM
	GROUP:		load=ROM2, run=CE1H
	{
	.cc_init 	{ _cc_init=.; .+=0x4000; }
	.cinit		/* These data will be copied by c_int00 */
	}
	.const:		>BMEM0
	.switch:	>BMEM0
	.bss:		>BMEM0
	.far:		>BMEM0
	.stack:		>BMEM0
	.sysmem:	>BMEM0
	.cio:		>BMEM0
	.data:		>BMEM0
	.febdata:	>BMEM1
}